VNGame/game/chapters/chapter1/arrival.rpy

# ── Persistent flags ──────────────────────────────────────────────────────────
# `checkpoint` (the rewind destination) is defined globally in script.rpy.
default rewind_used       = False
default purpose_chosen    = False
default silence_chosen    = False # here Sara learns that Luno asks everyone the same question


label arrival:
    scene bg training_yard
    with fade

    "The Iron Hollow training yard sits inside a converted warehouse district. Stone walls, packed dirt, the smell of old metal and new sweat."
    thinking "So this is where the Iron Hollow has its base."

    show sara neutral at left
    with easeinright

    thinking "Two others have arrived already. The boy over there is seems to know where to go, maybe I should ask him."
    thinking "Looks like the other one noticed me."

    show luno curious at right
    with easeinright

    luno "You're here for the recruitment?"
    sara "Yes. Where do I register?"
    luno "The man over at that table takes your name. Then we wait."
    thinking "Seems like she told him where to go."
    luno "I'm Luno. Been here a few days already — helping with the wounded from last month's job. I know how things run here if you need anything."
    thinking "That's a strong question right away."
    luno "So. Money, glory, or are you just bored?"
    jump .choice_screen

# Per-checkpoint reset: called by the shared rewind mechanic before it lands.
label .arrival_rewind_reset:
    $ rewind_used = True
    return

label .rewind_choice:
    if checkpoint is None:
        # No checkpoint created yet — can't rewind, move on.
        jump .kaeros_arrives

    menu:
        "[[Rewind]":
            jump rewind_to
        "Continue":
            pass

    # Resuming after "Continue": clear the checkpoint and move on.
    $ checkpoint = None
    $ rewind_used = False
    jump .kaeros_arrives

label .choice_screen:
    scene bg training_yard
    with fade

    show sara neutral at left

    show luno curious at right

    menu:
        "Why are you here?"
        "[[ Create Checkpoint ]" if checkpoint is None:
            # Store where a rewind should land, plus the reset label to call.
            $ checkpoint = "arrival.choice_screen"
            $ rewind_reset_label = "arrival.arrival_rewind_reset"
            scene black
            with dissolve
            "A flash. Sara's hand, signing something. A contract. The ink is red."
            scene bg training_yard
            with dissolve
            show sara neutral at left
            show luno curious at right
            jump .choice_screen

        "For the money, like anyone.":
            if rewind_used:
                jump .branch_money_post_rewind
            else:
                jump .branch_money

        "To find something worth doing." if not purpose_chosen:
            jump .branch_purpose

        "I'd rather not say.":
            jump .branch_silence

        "[[ You asked the others the same thing, didn't you. ]" if silence_chosen:
            jump .branch_sharp

label .branch_money:
    sara "Same reason as everyone else, I'd assume."
    luno "Honest. I can work with that."
    show luno amused at right
    luno "Though if money's the goal, you don't look like you need it."
    sara "Looks can be misleading."
    show luno neutral at right
    luno "Sure."
    "A pause. Just a half-beat too long."
    luno "They can be."
    "She doesn't push. But her eyes stay on Sara for another moment"
    jump .rewind_choice

label .branch_money_post_rewind:
    sara "Same reason as everyone else."
    luno "Sure."
    thinking "Unremarkable. Fine."
    "But when Sara finishes speaking, Luno's eyes linger — just a half-second longer than they should."
    show luno linger at right
    "Not suspicion. Not quite. More like the feeling of reaching for something that moved."
    show luno neutral at right
    thinking "Probably nothing."
    "But it wasn't nothing."
    jump .rewind_choice

label .branch_purpose:
    $ purpose_chosen = True
    sara "I'm not looking for money exactly. More... something to point myself at."
    "A beat. Something opens in Luno's expression — not warm, but something."
    show luno curious at right
    luno "Huh. That's not what I expected."
    sara "What did you expect?"
    luno "Something about honour. Or family legacy."
    show luno tilted at right
    luno "The clothes tell me nobility, and nobles are always on the look for honour."
    show sara pained at left
    sara "Honour is pointless when everyone is dead."
    thinking "I said too much."
    "She can feel it land — can feel Luno actually {i}looking{/i} at her now, not just watching."
    show luno soft at right
    luno "...Yeah. I know that feeling."
    thinking "I should go back. I told her way too much"
    jump .rewind_choice

label .branch_silence:
    $ silence_chosen = True
    sara "That's a fairly personal question for someone I've known thirty seconds."
    luno "Fair. I ask everyone. You don't have to answer."
    sara "...Then I won't."
    luno "That's an answer too."
    "She's not unfriendly. But Sara just became a question mark in Luno's mental ledger."
    jump .rewind_choice

label .branch_sharp:
    sara "You asked him the same thing."
    "She nods towards the guy who also arrived already."
    sara "Before I arrived."
    "Luno goes still. Not alarmed — but recalibrating."
    show luno still at right
    luno "...You were watching from outside the gate?"
    sara "The wall has gaps."
    luno "Most people don't bother to look."
    sara "I bother."
    "A pause. Luno is weighing something."
    luno "That's either very smart or very paranoid."
    sara "Both, usually."
    "Luno laughs — a real one, short and surprised."
    show luno laugh at right
    "But her eyes are sharper now, not warmer."
    show luno sharp at right
    jump .rewind_choice

label .kaeros_arrives:
    "Before the silence can settle, footsteps at the gate."
    show kaeros guarded at right
    kaeros "Is this the Iron Hollow?"
    luno "Looks like quite a few people are interested. You are at the right place."
    luno "Why do you want to join the Hollow?"
    mira "To protect people from evil---"
    kaeros "To make some money. Have to live off something around here."
    show luno laugh at right
    luno "I see, you have you priorities in order."
    show luno neutral at right
    luno "I like that. I am Luno, I arrived a while a go. Give the man over there your names and wait."
    sara "I am Sara, not sure what else to say."
    kaeros "I am Kaeros, and this is Mira."
    luno "She also just arrived you can register together."
    scene black
    with dissolve
    scene bg table
    show sara neutral at left
    # show iron_hollow_mercenary at right
    sara "The three of us are here to register."
    mercenary "Tell me your names and blessing."
    mira "I'm Mira, and I have a fire blessing. I can do a lot of things with it, like make bursts---"
    show kaeros guarded at left
    kaeros "I'm Kaeros, and I have a water blessing."
    kaeros "..."
    mercenary "Alright, what about you?"
    show sara neutral at left
    sara "My name is Sara, I have a wind blessing, but its really weak. My expertise is more with strategy."
    mercenary "It's rare to have a strategist join a band of mercenaries. I hope you can at least hold your own in combat."
    mercenary "I think fo-- five people are enough for now, grab Luno and that guy over there and we'll get started."
    jump first_test